home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Mind Run
/
Mind Run (1991)(Crealude)(FR)(M6)[!][CFI MINDRUM 91148].iso
/
so48.amos
/
so48.amosSourceCode
Wrap
AMOS Source Code
|
2008-12-15
|
38KB
|
1,086 lines
' So48 16 4 91
Set Buffer 20 : Close Workbench : Close Editor : Randomize Timer
If Exist("CFI:") : Dir$="CFI:" : Else Dir$="GIGUNA:GAMOS/" : End If
'
Dim TPTS(6),ZBUT(28),BBUT(28),ZBI(36),RSV(16,2),H(28),V(28),CPL(8,3),LS(5)
Dim XB(2),YB(2),Z(36),CUR(12,9,2),GAM$(12),PREF(5),SON(14,6,3),F$(36)
Global TEST,TPTS(),TEMPS,PTS,APTS,NBK,NBI,NB,NBUT,ZBUT(),BBUT(),DIFF,LS()
Global BUT$,SG$,SA$,SB$,ZBI(),RSV(),H(),V(),CPL(),XB(),YB(),Z(),CUR(),HCR,VCR
Global BBOULE,XT,YT,XH,YH,XR,YR,BCUR,HCURS,VCURS,XC,YC,XP,YP,CX,CY,SON()
Global BCP,CYCLETAPE,ETAPE,QST,MXETAPE,DIFF,DERANN$,ELTEMPS,GAUCHE
Global DUREE,VITESSE,BZN,MZ,ABANDON,RENOUV$,TSAB,TREN,LANGUE$,TEST$
Global LIGNE,DIT,GAM$(),PREF(),BOUTONS,BOUTONA,BOUTONB,FAITMUSE,FERMEDES
Global BOULBK,CRSBK,FLCHBK,CERVBK,BASEBLOCK,F$(),DC,DIT7,DIT8,FERME7
'
TEST$="Sounds" : TEST=3 : NBUT=1 : ZBUT(NBUT)=BZN+1 : INITEST
Load "banqueI/Titror"+LANGUE$+".ABK" : Paste Icon 20,48,TEST
FERME7=False
'
BANQBI["A.wurlyp",""] : EQUALISE
Procedure EQUALISE
Channel 2 To Bob 2 : Bob 2,15,127,L+1 : Wait Vbl
Amal 2,"R: L R1=R0+Z(3); A 1,(R1,5);P P P P P J R" : Amreg(2,0)=L+1
Amal On 2
End Proc
''''''''''''''''''''''' Boucle de test '''''''''''''''''''''''''''''''
While ETAPE<MXETAPE and Not ABANDON
PAUSEPOINTS : If Param=3 Then Amal Off : Bob Off : AJOUR : Exit
'
VOISTEST : PTS=Min(9,2*DIFF) : PTS=Max(3,PTS) : METPOINTS
VITESSE=60-5*DIFF : DUREE=$FFFF : Rem Max(1,3-DIFF)
For X=1 To 36 : ZBI(X)=0 : Next : Amal Off 2 : Bob Off 2 : AJOUR
VIDCUR[1]
Q$=Str$(QST)-" "
Erase 2 : Load "BanqueI/A.juke"+Q$+".abk" : Paste Icon 440-DC-20,75,1
B$="A.Wurly"+Q$ : BANQBI[B$,""] : TEMPS[0]
'If ETAPE<3 Then PARLE["listen",1]
NB=Min(6,DIFF+2) : For N=0 To 12 : For S=0 To 6 : For T=0 To 3
SON(N,S,T)=0 : Next : Next : Next : SON(0,0,0)=NB
On QST Proc SAME,NOREP,ISTRUMENT,INQLU,NONINC,RVERS,CONT,NOCONT
'
BRUIT[0,0,"tiroircaiss2"] : If BOUTONB and(PREF(4)=1) Then PREF(4)=0
GAUCHE[3,45]
For N=1 To NB : Bob N,,,NBK+16 : Wait Vbl : Next : Bob Off : AJOUR
Ink 39 : Bar 334-DC,0 To 634-DC,290 : If PTS<APTS Then DESTROYTOUT
FAITTOTAL : F=Free
Wend
RETOUR
''''''''''''''''''''''' Questions de SONS
Procedure SAME
BQSON1: Data 3,"BruitsA","Oiseau","klaxon"
BQSON2: Data 3,"varisol","rires","diversols"
BQSON3: Data 4,"dogs","percu","bebes","vents"
NS=1 : TIRE[0] : BANQSONS : NI=Param
For N=1 To NB
TIRE[NI] : GAM$(N)=F$(Param)
SON(N,0,0)=NS : Rem nombre de sons
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100 : Rem son brut
SON(N,S,1)=20000 : Rem fr�quence du son
If DIFF<3 Then SON(N,S,1)=15000+Rnd(10000)
SON(N,S,2)=50 : Rem dur�e
SON(N,S,3)=63 : Rem intensit�
Next
Next
Z(0)=1+Rnd(NB-2) : GAM$(NB+1)=GAM$(Z(0))
For S=0 To NS : For T=0 To 3 : SON(NB+1,S,T)=SON(Z(0),S,T) : Next : Next
QUESTDESON["same"]
End Proc
Procedure NOREP
NS=1 : TIRE[0] : TIRB[0] : BANQSONS : NI=Param
' Tire l'isol�
TIRE[NI] : S$=F$(Param) : TIRB[NB] : Z(0)=Param : GAM$(Z(0))=S$
' Tire un couple ou un trio
TIRE[NI] : S$=F$(Param)
For X=1 To 2-(NB=2*(NB/2)) : TIRB[NB] : GAM$(Param)=S$ : Next
' comble le reste
If NB>4
TIRE[NI] : S$=F$(Param) : For X=1 To 2 : TIRB[NB] : GAM$(Param)=S$ : Next
End If
For N=1 To NB
SON(N,0,0)=NS
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100
SON(N,S,1)=20000
SON(N,S,2)=50
SON(N,S,3)=63
Next
Next
GAM$(NB+1)="" : Rem ne jouera pas du juke
QUESTDESON["NotRepeated"]
End Proc
Procedure ISTRUMENT
NS=2 : TIRE[0] : TIRB[0] : INS$="varisol/sol" : NI=10
' Tire l'isol�
TIRE[NI] : S$=INS$+Str$(Param)-" "
TIRB[NB] : Z(0)=Param : GAM$(Z(0))=S$
' Tire un couple ou un trio
TIRE[NI] : S$=INS$+Str$(Param)-" "
For X=1 To 2-(NB=2*(NB/2)) : TIRB[NB] : GAM$(Param)=S$ : Next
' comble le reste
If NB>4
TIRE[NI] : S$=INS$+Str$(Param)-" "
For X=1 To 2 : TIRB[NB] : GAM$(Param)=S$ : Next
End If
For N=1 To NB
SON(N,0,0)=NS
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100
DIATON : SON(N,S,1)=Param
SON(N,S,2)=25
SON(N,S,3)=63
Next
Next
GAM$(NB+1)="" : QUESTDESON["Instrument"]
End Proc
Procedure INQLU
NS=1 : TIRE[0] : INS$="varisol/sol" : NI=10
TIRE[NI] : I$=INS$+Str$(Param)-" "
For N=1 To 2*NB
GAM$(N)=I$
SON(N,0,0)=NS
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100
DIATON : SON(N,S,1)=Param
SON(N,S,2)=50
SON(N,S,3)=63
Next
Next
Z(0)=1+Rnd(NB-2) : K=1+Rnd(NB-1)
For S=0 To NS : For T=0 To 3 : SON(NB+K,S,T)=SON(Z(0),S,T) : Next : Next
GAM$(NB+K)=GAM$(Z(0))
SON(NB+1,0,1)=2
QUESTDESON["Included"]
End Proc
Procedure NONINC
NS=1 : TIRE[0] : INS$="varisol/sol" : NI=13
For N=1 To 2*NB
TIRE[NI] : GAM$(N)=INS$+Str$(Param)-" "
SON(N,0,0)=NS
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100
SON(N,S,1)=20000
If DIFF<3 Then DIATON : SON(N,S,1)=Param
SON(N,S,2)=50
SON(N,S,3)=63
Next
Next
TIRE[0] : TIRE[NB] : Z(0)=Param : R=NB+1+Rnd(NB-2)
For N=NB+1 To 2*NB
If N<>R
TIRE[NB] : K=Param
For S=0 To NS : For T=0 To 3 : SON(N,S,T)=SON(K,S,T) : Next : Next
GAM$(N)=GAM$(K)
End If
Next
SON(NB+1,0,1)=2 : QUESTDESON["NotIncluded"]
End Proc
Procedure RVERS
NS=Min(6,DIFF+2) : SMP=3
'Load "MRsons/"+"bebe1.sbk",8
'Sam Bank 8
For N=1 To NB : SON(N,0,0)=NS : SON(N,0,1)=0
Do
For S=1 To NS
Do : Rem La hauteur est <> des pr�c�dentes
SON(N,S,1)=38+Rnd(12) : Exit If S=1
For T=1 To S-1 : Exit If SON(N,S,1)<>SON(N,T,1),2 : Next
Loop
Next
Exit If N=1
For T=1 To N-1 : Rem L'objet est <>
For S=1 To NS : Exit If SON(T,S,1)<>SON(N,S,1),3 : Next
Next
Loop
For S=1 To NS : Rem SON(N,S,0)=1+Rnd(SMP-1)
SON(N,S,2)=10+10*Rnd(1)
SON(N,S,3)=40+Rnd(23) : Next
Next
Z(0)=1+Rnd(NB-2) : GAM$(NB+1)="&"
For S=0 To NS : For T=0 To 3 : SON(NB+1,S,T)=SON(Z(0),S,T) : Next : Next
For S=1 To NS/2
Swap SON(NB+1,S,1),SON(NB+1,NS-S+1,1)
Swap SON(NB+1,S,2),SON(NB+1,NS-S+1,2)
Next
QUESTDESON["Reverse"]
End Proc
Procedure CONT
FERME7=True
NS=1 : TIRE[0] : INS$="varisol/sol" : NI=10
For N=1 To NB+1
TIRE[NI] : GAM$(N)=INS$+Str$(Param)-" "
SON(N,0,0)=NS
SON(N,0,1)=0 : Rem m�lodie
For S=1 To NS
SON(N,S,0)=100
SON(N,S,1)=20000
If DIFF<3 Then DIATON : SON(N,S,1)=Param
SON(N,S,2)=50
SON(N,S,3)=63
Next
Next
Z(0)=1+Rnd(NB-2) : GAM$(NB+2)=GAM$(Z(0))
For S=0 To NS : For T=0 To 3 : SON(NB+2,S,T)=SON(Z(0),S,T) : Next : Next
SON(NB+1,0,1)=3 : SON(0,0,1)=1 : QUESTDESON["Contained"]
End Proc
Procedure NOCONT
'Load "MRsons/"+"samples.abk",8 : SMP=3 : Sam Bank 8
TIRE[0] : TIRE[12] : S0=Param+38 : Z(0)=1+Rnd(NB-1)
For N=1 To NB : SON(N,0,0)=2 : SON(N,0,1)=1 : SON(N,1,0)=0
If N=Z(0)
SON(N,1,1)=S0
Else
TIRE[12] : SON(N,1,1)=Param+38
End If
SON(N,1,2)=50 : SON(N,1,3)=63
TIRE[12] : SON(N,2,0)=0 : SON(N,2,1)=Param+38 : SON(N,2,2)=50
Next
SON(NB+1,0,0)=1 : SON(NB+1,1,0)=0
SON(NB+1,1,1)=S0 : SON(NB+1,1,2)=50 : SON(NB+1,1,3)=63
GAM$(NB+1)="&" : QUESTDESON["NotContain"]
End Proc
'
'
Procedure BANQSONS
Data 16,"BruitsA/B",17,"Oiseau/O",19,"Klaxon/K",10,"AnimoNb/A",30
Data "bebesnew/",10,"eauxnew/",11,"exploznew/",11,"moteleknew/",10
Data "percu/",9,"dogs/d",8,"insekt/",11,"cloches/",12
Data "ClochesVar/",10,"MaxRires/",18,"diversols/",10,"motexplo/",10
Restore : Read N : N=1+Rnd(N-1) : For X=1 To N : Read B$,NI : Next
For X=1 To NI : F$(X)=B$+Str$(X)-" " : Next
End Proc[NI]
Procedure DIATON
Data 196,207.65,220,233.08,246.94
Data 261.63,277.18,293.66,311.13,329.63,349.23,370,392,415.3
Data 440,466.16,493.88,523.25
N=1+Rnd(16) : Restore : For X=1 To N : Read F : Next : F=20000/392*F
End Proc[F]
Procedure QUESTDESON[Q$]
MS6: Data 430,20,1,0,490,20,2,0,380,60,1,1,540,60,2,1,370,115,1,2,550,115,2,2
MS5: Data 460,20,2,0,385,50,1,1,535,50,2,1,370,115,1,2,550,115,2,2
MS4: Data 430,20,1,0,490,20,2,0,380,60,1,1,540,60,2,1
MS3: Data 460,20,2,0,380,60,1,1,540,60,2,1
Restore "MS"+Str$(NB)-" "
PARLE[Q$,1] : Wait 50
For N=1 To NB : Read H(N),V(N),CX,CY : Add H(N),(-DC-15)
CUR(CX,CY,0)=H(N) : CUR(CX,CY,1)=V(N) : CUR(CX,CY,2)=BZN+N
HCR=Max(CX,HCR) : VCR=Max(CY,VCR)
MZ=BZN+N
Next
If GAM$(NB+1)<>"" : Rem Si le juke joue
CX=2 : Add CY,1 : HCR=Max(CX,HCR) : VCR=Max(CY,VCR)
CUR(CX,CY,0)=477-DC-15 : CUR(CX,CY,1)=150 : CUR(CX,CY,2)=BZN+NB+1
End If
INICURS[CX,CY]
If GAM$(NB+1)<>"" Then VIBRE[NB+1] : Wait 50
For N=1 To NB
Bob N,H(N),V(N),1 : Wait Vbl : Bob BCUR,H(N),V(N), : Wait Vbl
VIBRE[N] : If SON(1,1,0)<100 Then Wait 25
Next
'
'
INICURS[2,1]
VITESSE=$FFFF : TSAB=Timer+49
Do : FAIXAMCUR : Exit If Param : JOUESON : Loop
If FERME7
A$="MRbruits/Brt4.sbk" : If Not(Exist(A$)) : A$="df0:Brt4.sbk" : End If
Load A$,7 : FERME7=False
End If
End Proc
Procedure JOUESON
N=MZ-BZN
If N<NB+1 Then Bob N,,,2 : Wait Vbl
VIBRE[N]
If N<NB+1 Then Bob N,,,1 : Wait Vbl
End Proc
Procedure VIBRE[N]
On ERR Goto FINDEPROC
V=%101
If SON(N,0,1)=0 : Rem melodies
If SON(N,1,0)>99
A$="MRsons/"+GAM$(N) : Open In 1,A$ : L=Lof(1) : Close 1
If L>64000 : Pop Proc : End If : Bload A$,Start(6)
End If
For S=1 To SON(N,0,0) : Volume V,SON(N,S,3)
If SON(N,S,0)<100
If SON(N,S,0)>0
Sample SON(N,S,0) To V
Else
Wave 1 To V
End If
Play V,SON(N,S,1),SON(N,S,2)
Else
While Timer<DIT : Wend : F=SON(N,S,1)
Sam Raw V,Start(6)+104,L,F : DIT=Timer+Max(SON(N,S,2),50*L/F)
End If
Next
End If
If SON(N,0,1)=1 : Rem accords
If SON(N,1,0)>0
Sample SON(N,1,0) To V
Else
Wave 1 To %1111
End If
Play %101,SON(N,2,1),0
Play %1010,SON(N,1,1),SON(N,1,2)
Play %1111,0,0
End If
If SON(N,0,1)=2 : Rem S�quence question (les inclus)
For N=NB+1 To 2*NB
A$="MRsons/"+GAM$(N) : Open In 2,A$ : L=Lof(2) : Close 2
If L>64000 : Pop Proc : End If
Bload A$,Start(6)
For S=1 To SON(N,0,0)
Volume V,SON(N,S,3)
While Timer<DIT : Wend : F=SON(N,S,1)
Sam Raw V,Start(6)+104,L,F : DIT=Timer+Max(SON(N,S,2),50*L/F)
Next
Wait 40
Next
End If
If SON(N,0,1)=3 : Volume V,63 : Rem les superpos�s
For X=1 To 2
A$="MRsons/"+GAM$(NB+X)
Open In 2,A$ : L=Lof(2) : Close 2 : If L>64000 : Pop Proc : End If
LS(X)=L : Bload A$,Start(5+X)
Next
While Timer<DIT : Wend
LAVOIX: Data %1,%100
Restore LAVOIX
For X=1 To 2
F=SON(NB+X,1,1) : Read VS : Volume VS,63
Sam Raw VS,Start(5+X)+104,LS(X),F
Next : Wait 20
L=Max(LS(1),LS(2)) : DIT=Timer+Max(SON(NB+X,1,2),50*L/F)
End If
While Timer<DIT : Wend : Play %1111,0,0
Wait 10
FINDEPROC:
End Proc
Procedure FAIXAMCUR
' OPTION true fin de test
TREN=Timer+VITESSE : OPTION=True
Do
CURSEUR[1] : Exit If PTS<1
If BOUTONB Then MZ=1
If MZ=1 Then CLIQUE[13] : PTS=0 : Exit : Rem Puis destroytout
If MZ=2 : CLIQUE[14] : PARLE[DERANN$,1] : INICURS[CX,CY]
BOUTONS=False : End If
If MZ=3 Then CLIQUE[15] : PTS=0 : ABANDON=True : Exit
Exit If PTS<1 or DUREE<1
If BOUTONS
JOUESON
If MZ=BZN+Z(0) : BRUITB[1] : While Timer<DIT7 : Wend : Exit
Else
TSAB0=TSAB-Timer
Dec PTS : METPOINTS : DESTROYPT : Exit If PTS<1
If DIFF>1 : Dec PTS : METPOINTS : DESTROYPT : Exit If PTS<1 : End If
If DIFF>3 : Dec PTS : METPOINTS : DESTROYPT : Exit If PTS<1 : End If
TSAB=TSAB0+Timer : While Mouse Key : Wend
End If
End If
Loop
End Proc[OPTION]
Procedure ALEAMUS[S]
If S=0 Then FAITMUSE=0 : Volume 15,0 : Pop Proc
FAITMUSE=1 : Add DIT,150
End Proc
Procedure MUSE
If PREF(5)=1 Then Pop Proc
If FAITMUSE=0 Then Pop Proc
Data 261.63,277.18,293.66,311.13,329.63,349.23,370,392,415.3
Data 440,466.16,493.88,523.25
N=1+Rnd(11) : Restore : For X=1 To N : Read F : Next : F=20000/392*F
A$="mrsons/voliere/O"+Str$(1+Rnd(19))-" "
If Length(6)<1 Then Reserve As Chip Work 6,$FFFF
Open In 1,A$ : L=Lof(1) : Close 1 : Bload A$,Start(6)
VOIX=Rnd(1)+4*Rnd(1) : PEDALE=20+Rnd(43)
Volume VOIX,PEDALE : Sam Raw VOIX,Start(6)+104,L,F
DIT=Timer+50*L/F+Rnd(100)
End Proc
'
'
' PROCEDURES GENERALES
'
Procedure INITEST
DC=0 : Rem nouvelles coordonn�es / petit �cran
If Screen=7 : PRENDVAR
Else Load Iff "decors/"+Mid$(TEST$,1,2),0 : Double Buffer
LANGUE$="Ang" : PREF(1)=1 : PREF(3)=2 : End If
Colour 0,0 : Colour Back 0 : Wait Vbl : View
Hide On : Limit Mouse : MXETAPE=40 : CYCLETAPE=8 : GAUCHE=True : Curs Off
XB(0)=280 : YB(0)=46 : Rem Suite
XB(1)=295 : YB(1)=63 : Rem Help
XB(2)=278 : YB(2)=79 : Rem Encore
BCUR=63 : Rem N� de bob du curseur
XP=282 : YP=4 : APTS=0 : BBOULE=15 : Rem bob des points sur le boulier
XC=253 : YC=177 : Rem compteur d'�tapes
XT=209 : YT=24 : Rem compteur du total
BOULBK=1 : CRSBK=2 : FLCHBK=3 : CERVBK=4 : BASEBLOCK=4 : Rem Blocks de base
BZN=8
For X=1 To 15 : Erase X : Next
Erase 7 : Reserve As Chip Work 7,7520 : Load "MRbruits/Brt0.sbk",7
'
BANQBI["",""]
'
Reserve Zone 35 : Limit Mouse
ETAPE=0 : QST=ETAPE : DIFF=1 : ELTEMPS=100
'
' Boulier des points par �cran (Block BOULBK pour toutes les boules)
Get Block BOULBK,25+XP-DC,5+YP,10,10,1
'
' Compteur d'�tapes (Block CRSBK pour le curseur, initialis� ici)
HCURS=XC-DC : VCURS=YC-3*ETAPE : Get Block CRSBK,HCURS,VCURS,22,17,1
Paste Icon HCURS,VCURS,12
'
' Fl�ches (block FLCHBK, actualis� chaque fois)
'For I=0 To 2 : Set Zone I+1,XB(I)+7-DC,YB(I)+7 To XB(I)+19-DC,YB(I)+19
'Next
'
' Difficult� (Block CERVBK actualis� chaque fois, initialis� ici)
AZDIF: Data 284,172,311,183
Data 285,161,314,172
Data 284,149,317,161
Data 285,133,321,149
Data 285,113,326,133
Restore AZDIF : Read H,V,H1,V1 : Add H,-DC : Add H1,-DC
Get Block CERVBK,H,V,H1-H,V1-V,1 : DIFF[0,DIFF]
Restore AZDIF
'For Y=4 To 8 : Read H,V,H1,V1 : Set Zone Y,H,V To H1,V1 : Next
'
' Plage de travail (Block 1, de type "c")
'Get Cblock 1,334,0,300,290
Get Cblock 1,0,0,8,2
TEMPS[0] : PARLE["Start",2]
End Proc
Procedure PAUSEPOINTS
BZDIF: Data 284,172,311,183,285,161,314,172,284,149,317,161
Data 285,133,321,149,285,113,326,133
ALEAMUS[1] : A=0 : CX=1 : CY=0
If(PREF(4)=0) or(ETAPE<1)
Repeat
VIDCUR[0]
For I=0 To 2
CUR(1,I,0)=XB(I)-DC : CUR(1,I,1)=YB(I) : CUR(1,I,2)=I+1
Next
Restore BZDIF : For Y=4 To 8
Read H,V,H1,V1 : Add H,-DC : Add H1,-DC
CUR(1,11-Y,0)=H : CUR(1,11-Y,1)=V : CUR(1,Y-1,2)=12-Y : Next
CUR(0,2,0)=194-DC : CUR(0,2,1)=85 : CUR(0,2,2)=9
INICURS[CX,CY] : HCR=1 : VCR=7
CURSEUR[0] : A=Param : If BOUTONB : MZ=3 : End If
If(A=27) or(MZ=2) : Rem pr�sentations
ALEAMUS[0]
If MZ=2 : CLIQUE[14] : CX=1 : CY=1 : INICURS[CX,CY] : End If
DEPLACE: Data 1,0,1,1,1,2,0,2,1,2,1,1,1,0,1,1,1,2,1,3
Bob BCUR,CUR(1,0,0),CUR(1,0,1), : Wait Vbl : PARLE["Arrows",2]
Restore DEPLACE : For X=1 To 10
Read H,V
BRUITB[3] : Bob BCUR,CUR(H,V,0),CUR(H,V,1), : Wait Vbl
TEMPS=Timer+50
Repeat : K1=Mouse Key : Until Timer>TEMPS or K1>0
Exit If K1
Next
If K1<1
PRESENTE: Data 1,0,"Advance",1,1,"Help",1,2,"Main"
Data 0,2,"Preferences"
Wait 50 : PARLE["select",2] : Wait 250 : Restore PRESENTE
For X=1 To 4
Read H,V,A$ : Bob BCUR,CUR(H,V,0),CUR(H,V,1), : Wait Vbl
PARLE[A$,2]
T=Timer+250 : Repeat : K2=Mouse Key : Until Timer>T or K2>0
Exit If K2
Next
If K2<1
PARLE["Level",2] : Rem Amal Off 15 : Wait Vbl
For X=1 To 5 : Bob BCUR,CUR(1,8-X,0),CUR(1,8-X,1), : Wait Vbl
T=Timer+50
Repeat : K3=Mouse Key : Until Timer>T or K3>0
Exit If K3
Bob BCUR,,,NBK+16 : Wait Vbl : Rem AJOUR : DIFF[X]
'Bob BCUR,,,NBK+17 : Wait Vbl : Wait 40
Next
If K3<1
T=Timer+100
Repeat : K=Mouse Key : Until Timer>T or K>0
End If
End If
'DIFF[1]
End If
MZ=0 : INICURS[1,0] : ALEAMUS[1] : Wait 50
End If
If A=43
ETAPE=Min(39,ETAPE+1) : ETAPE[ETAPE] : Inc QST : MZ=0
End If
If A=45
ETAPE=Max(0,ETAPE-1) : ETAPE[ETAPE] : QST=Max(0,QST-1) : MZ=0
End If
If 3<MZ and MZ<9
BRUITB[100] : Amal Off 15 : Bob BCUR,,,NBK+16 : AJOUR : DIFF[DIFF,MZ-3]
End If
If MZ=9 : ALEAMUS[0] : BRUITB[50]
P=1 : If Screen=3 : P=2 : End If : PREFERENCES[P] : ALEAMUS[1]
MZ=0
If DC<1 : BANQBI["A.wurlyp",""] : EQUALISE : End If
End If
Until(MZ=1) or(MZ=3) or BOUTONB
Else
MZ=1
End If : ALEAMUS[0]
Wait 1+50*PREF(4) : Rem If(PREF(4)=1) and(ETAPE>0) Then MZ=1
If MZ=1
ALEAMUS[0] : DIT=0
CLIQUE[13] : Inc ETAPE : Inc QST
If QST>CYCLETAPE
A=DIFF : QST=1 : DIFF=Min(DIFF+1,5) : DIFF[A,DIFF]
End If
ETAPE[ETAPE] : TEMPS[0]
End If
If(MZ=3) or BOUTONB Then CLIQUE[15]
Amal Off 15 : Bob Off BCUR : Bob Clear : AJOUR
End Proc[MZ]
Procedure INICURS[CX,CY]
Limit Mouse
If Chanan(15) Then Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1), : Pop Proc
Channel 15 To Bob BCUR : Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1),NBK+17
Wait Vbl : Amal 15,"A 0,(R1,46)(R2,4)"
Amreg(15,1)=NBK+17 : Amreg(15,2)=NBK+18 : Amal On 15 : Clear Key
End Proc
Procedure CURSEUR[C]
BOUTONA=False : BOUTONB=False : BOUTONS=False
Clear Key
Repeat
Repeat : T1=Timer+50
For X=1 To 10
X=X Mouse : Y=Y Mouse : Wait 3 : U=X Mouse : V=Y Mouse
Exit If X=U and Y=V
Next
X Mouse=150 : Y Mouse=100 : MX0=X Mouse : MY0=Y Mouse : DM=0
Repeat
If Timer>DIT Then MUSE
If C=1 : Rem En cours de question
If Timer>TSAB : TEMPS[1] : TSAB=Timer+49 : End If
If(PTS<1) or(DUREE<1) : MZ=0 : Exit 3 : End If
If Timer>TREN : A=0 : Exit 3 : End If
End If
If C=2 : Rem En menu principal
If Timer>T1
Restore "ETOILE"
For X=1 To 1+Rnd(21) : Read A,B : Next
Bob 3,A,B, : Wait Vbl
T2=Timer+10+Rnd(20) : T1=T2+200
End If
If Timer>T2
Bob 3,-20,, : T1=Timer+50+50*Rnd(2) : T2=T1+200
End If
End If
MX=X Mouse : MY=Y Mouse : A$=Inkey$
Until A$<>"" or Mouse Key or Abs(MX0-MX)>DM or Abs(MY0-MY)>DM
K=Mouse Key : R=Asc(A$)
A=-28*(MX-MX0>DM)-29*(MX0-MX>DM)-30*(MY0-MY>DM)-31*(MY-MY0>DM)
If(R>27) and(R<32) Then A=R
X=CX : Y=CY
If(A=28) Then Add X,1
If(A=29) Then Add X,-1
If(A=30) Then Add Y,-1
If(A=31) Then Add Y,1
Until((X<0)+(Y<0)+(X>HCR)+(Y>VCR)=0)
If(X<>CX) or(Y<>CY)
If(CUR(X,Y,0)=0) and(CUR(X,Y,1)=0)
If(A=28) or(A=29)
Repeat : Add Y,-1,0 To VCR
Until((CUR(X,Y,0)<>0) or(CUR(X,Y,1)<>0))
End If
If(A=30) or(A=31)
Repeat : Add X,1,0 To HCR
Until((CUR(X,Y,0)<>0) or(CUR(X,Y,1)<>0))
End If
End If
BRUITB[3] : CX=X : CY=Y : Bob BCUR,CUR(CX,CY,0),CUR(CX,CY,1),
Exit If C=2
End If
Until(K>0)+(R=43)+(R=45)+(R=27)+(R=13)
MZ=CUR(CX,CY,2)
BOUTONS=(K>0)+(R=13) : BOUTONA=(K=1)+(K=3)+(R=13) : BOUTONB=(K>1)
End Proc[R]
Procedure VIDCUR[A]
For X=0 To 12 : For Y=0 To 9 : For Z=0 To 2 : CUR(X,Y,Z)=0
Next : Next : Next
If A=1 : Rem situe les trois fl�ches
For I=0 To 2 : CUR(0,I,0)=XB(I)-DC : CUR(0,I,1)=YB(I)
CUR(0,I,2)=I+1 : Next
HCR=1 : VCR=2
End If
End Proc
Procedure PARLE[A$,T]
If Length(6)<1 Then Erase 6 : Reserve As Chip Work 6,$FFFF
If PREF(1)<1 Then Pop Proc
While Timer<DIT : Wend
Volume %101,63 : DERANN$=A$
T$=TEST$ : If T=2 Then T$="General"
SEX$=Mid$("FM",1+Rnd(1),1) : If Instr("JapIta",LANGUE$) Then SEX$="F"
F$="Paroles/"+T$+"/"+LANGUE$+SEX$+"/"+A$
If Not Exist(F$) Then Pop Proc
Open In 1,F$ : L=Lof(1) : Close 1
If L>$FFFF Then Pop Proc
S6=Start(6) : Bload F$,S6 : Volume %101,63 : Sam Raw %101,104+S6,L,20000
DIT=Timer+(L/400)+20
If Exist(F$+Chr$(50))
While Timer<DIT : Wend : F$=F$+Chr$(50)
Open In 1,F$ : L=Lof(1) : Close 1
If L>64000 : Pop Proc : End If
Bload F$,S6 : Sam Raw %101,104+S6,L,20000
DIT=Timer+(L/400)+20
End If
If T=1 Then While Timer<DIT : Wend
End Proc
Procedure BRUIT[F,V,A$]
If Length(6)<1 Then Reserve As Chip Work 6,$FFFF
If PREF(2) Then Pop Proc
While Timer<DIT : Wend
S=20000 : If F<>0 Then S=1000*F
If L>65430 Then Pop Proc
Open In 1,"MRbruits/"+A$ : L=Lof(1) : Close 1
Bload "MRbruits/"+A$,Start(6)
Volume %1010,63 : If V<>0 Then Volume %1010,V
Sam Raw %1010,Start(6)+104,L,S : DIT=Timer+L/400
End Proc
Procedure BRUITB[N]
If FERME7 Then Pop Proc
F=20000 : If N=100 Then N=3 : F=30000
If N=50 Then N=3 : F=10000
S0=Start(7) : S=Leek(S0+8*N) : L=Leek(S0+8*N+4)
Volume %1010,63 : Sam Raw %1010,S+S0+105,L-105,F : DIT7=Timer+L/400
End Proc
Procedure TEMPS[T]
' Mettre sur la voix
If T=0 : TEMPS=DIFF-1 : Else BRUITB[2] : End If
Inc TEMPS
If TEMPS>10
Dec PTS : METPOINTS : DESTROYPT : Dec DUREE
If DUREE<1 or PTS<1 : Pop Proc : End If
TEMPS=DIFF
End If
Paste Icon 578-DC,5,TEMPS+15 : Wait Vbl
End Proc
Procedure CLIQUE[I]
Amal Off 1 : Bob Off BCUR : Bob Clear : AJOUR
BRUITB[50] : H=XB(I-13)-DC : V=YB(I-13)
Get Block FLCHBK,H,V,40,40,1 : Paste Icon H,V,I : While Mouse Key : Wend
ABLOC[FLCHBK]
End Proc
Procedure AIDE
End Proc
Procedure ETAPE[ETAPE]
Update : Update Off : Wait Vbl
Bob Clear : Put Block CRSBK,XC-DC, : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block CRSBK,XC-DC, : Bob Draw : Screen Swap : Wait Vbl
Update On
HCURS=XC-DC : VCURS=YC-3*ETAPE
Get Block CRSBK,HCURS,VCURS,22,17,1 : Paste Icon HCURS,VCURS,12
End Proc
Procedure DIFF[I1,I2]
ZD1: Data 284,172,311,183
ZD2: Data 285,161,314,172
ZD3: Data 284,149,317,161
ZD4: Data 285,133,321,149
ZD5: Data 285,113,326,133
If I1>0
Restore "ZD"+Str$(I1)-" " : Read H : Add H,-DC
Update : Update Off : Wait Vbl
Bob Clear : Put Block CERVBK,H, : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block CERVBK,H, : Bob Draw : Screen Swap : Wait Vbl
Update On
End If
I=Min(I2,5) : Restore "ZD"+Str$(I)-" " : Read H,V,H1,V1
Add H,-DC : Add H1,-DC
Get Block CERVBK,H,V,H1-H,V1-V,1 : Paste Icon H,V,6+I
DIFF=I
End Proc
Procedure FAITTOTAL
I=PTS : B=BBOULE
PT1: Data 25,5
PT2: Data 14,5
PT3: Data 3,5
PT4: Data 25,16
PT5: Data 14,16
PT6: Data 3,16
PT7: Data 25,27
PT8: Data 14,27
PT9: Data 3,27
If PTS>0
Amal Off : Bob Off : AJOUR
A$="A 1,(R2,7)(R3,1)(R4,1);M R0,0,5;M 0,R1,3;M -4,0,4"
For X=I To 1 Step -1
Dec PTS : METPOINTS : Inc TPTS(TEST)
Restore "PT"+Str$(PTS+1)-" " : Read H,V : H=XP+H-DC : V=YP+V
Dec B : Channel B To Bob B : Bob B,H,V,NBK+1 : Wait Vbl
Amal B,A$
Amreg(B,0)=XT+55-H-DC : Amreg(B,1)=YT+4-V : Amreg(B,2)=NBK+1
Amreg(B,3)=NBK+15 : Amreg(B,4)=NBK+16
Amal On B
If X=I : Sam Loop On : BRUIT[0,0,"Bobloc"] : End If
METTOTAL["+",TPTS(TEST),XT,YT] : Wait Vbl
Next
While Chanmv(B) : Wend
Bob Off : Bob Clear : Sam Loop Off
End If
End Proc
Procedure METTOTAL[D$,N,X0,Y0]
If D$="+" or N>0
U=N mod 10 : N=(N-U)/10
If N>0
D=N mod 10 : N=(N-D)/10
If N>0
C=N mod 10
End If
End If
Paste Icon X0-DC,Y0,27+C : Wait Vbl
Paste Icon X0+13-DC,Y0,27+D : Wait Vbl
Paste Icon X0+26-DC,Y0,27+U : Wait Vbl
Else
Paste Icon X0,Y0,26
Paste Icon X0+13,Y0,26
Paste Icon X0+26,Y0,26 : Paste Icon X0+26,Y0,26
End If
End Proc
Procedure METPOINTS
APT1: Data 25,5
APT2: Data 14,5
APT3: Data 3,5
APT4: Data 25,16
APT5: Data 14,16
APT6: Data 3,16
APT7: Data 25,27
APT8: Data 14,27
APT9: Data 3,27
If PTS<0 Then APTS=0 : Pop Proc
If PTS>APTS
For X=Max(1,APTS+1) To PTS
Restore "APT"+Str$(X)-" " : Read H,V : Paste Icon XP+H-DC,YP+V,1
Next
Else
For X=APTS To Max(PTS+1,1) Step -1
Restore "APT"+Str$(X)-" "
Read H,V : H=XP+H-DC : V=YP+V : AUTOBLOC[BOULBK,H,V]
Next
End If
APTS=PTS
End Proc
Procedure DESTROYPT
If PTS<0 Then Pop Proc
While FERMEDES : Wend : FERMEDES=True
BPT1: Data 25,5
BPT2: Data 14,5
BPT3: Data 3,5
BPT4: Data 25,16
BPT5: Data 14,16
BPT6: Data 3,16
BPT7: Data 25,27
BPT8: Data 14,27
BPT9: Data 3,27
BRUITB[4] : Restore "BPT"+Str$(PTS+1)-" " : Read H,V
B=BBOULE-1 : Dec BBOULE : If BBOULE=12 Then BBOULE=15
BL=B+20
DSP$="A 1,(R1,R0)(R1+1,R0)(R1+2,R0)(R1+3,R0)(R1+4,R0)(R1+5,R0)(R2,1)"
DSP$=DSP$+";M 0,100,62"
Channel B To Bob BL : Bob BL,XP+H-DC,YP+V,NBK+3 : Wait Vbl : Amal B,DSP$
Amreg(B,0)=10 : Amreg(B,1)=NBK+3 : Amreg(B,2)=NBK+16 : Amal On B
FERMEDES=False
'While Chanmv(B) or Chanan(B) : Wend
End Proc
Procedure DESTROYTOUT
Data 25,5,14,5,3,5,25,16,14,16,3,16,25,27,14,27,3,27
If APTS<1 Then Pop Proc
BRUIT[0,0,"perdu!"] : Bob Off : Bob Clear : Amal Off
Restore : For P=1 To APTS : Read H,V
H(P)=XP+H-DC : V(P)=YP+V : AUTOBLOC[BOULBK,H(P),V(P)] : Next
For P=1 To APTS : Bob P,H(P),V(P),NBK+3 : Wait Vbl : Next
DSP$="A 1,(R1,R0)(R1+1,R0)(R1+2,R0)(R1+3,R0)(R1+4,R0)(R1+5,R0)(R1+13,1)"
DSP$=DSP$+";M 0,100,62"
For P=APTS To 1 Step -1
Channel P To Bob P : Bob P,H(P),V(P), : Wait Vbl
Amal P,DSP$ : Amreg(P,0)=10 : Amreg(P,1)=NBK+3 : Amal On P
Next
While Chanmv(1) or Chanan(1) : Wend : Wait Vbl : Wait 25
APTS=0 : PTS=0
End Proc
Procedure DROITE[E,D]
If Not(GAUCHE) Then Pop Proc
Amal Off : Wait Vbl
Channel 1 To Screen Offset E : Screen E : Screen To Front E
Amal 1,"M 20,0,5;M R0,0,R1;M 20,0,5"
Amreg(1,0)=D : Amreg(1,1)=20 : If D<100 Then Amreg(1,1)=5
Amal On 1 : While Chanmv(1) : Wend : GAUCHE=False
End Proc
Procedure GAUCHE[E,D]
If GAUCHE Then Pop Proc
Amal Off : Wait Vbl
Channel 1 To Screen Offset E : Screen E
Amal 1,"M -20,0,5 ;M R0,0,R1;M -20,0,5"
Amreg(1,0)=-D : Amreg(1,1)=20 : If D<100 Then Amreg(1,1)=5
Amal On 1 : While Chanmv(1) : Wend : GAUCHE=True
End Proc
Procedure DIAPHRAGME[A,B]
' montre la moiti� gauche de B arrivant en diaphragme sur A
Autoback 0 : Screen To Front A
For X=1 To 59 Step 2
H0=170-X : H1=170+X : V0=128-X : V1=128+X
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
For X=60 To 130 Step 10
H0=170-X : H1=170+X : V0=128-X : V1=128+X
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
For X=131 To 176 Step 20
H0=170-X : H1=170+X : V0=0 : V1=260
Screen Swap : Wait Vbl : Screen Copy B,H0,V0,H1,V1 To A,H0,V0
Next
Screen To Front B : Screen B : Rem Screen Close A
End Proc
Procedure CLOCK[X,Y]
Change Mouse 3 : X Mouse=X : Y Mouse=Y : Show On
End Proc
Procedure PASSECRAN[A$,E,F,G]
Screen Open 2,360,270,64,Lowres : Flash Off
Get Palette E : Screen To Front E
Screen Copy E,0,0,360,270 To 2,0,0 : Screen Close E
Load Iff A$,F : Flash Off : Get Palette 2
Screen To Front 2 : Screen F
If G=1 Then Screen Close 2 : Double Buffer
End Proc
Procedure BANQBI[B$,I$]
CLOCK[280,60] : Amal Off : Bob Off : AJOUR : Erase 1 : Erase 2
If B$=""
NBK=0 : Load "BanqueB/BoulesC.abk"
Else
Load "BanqueB/"+B$+".abk" : NBK=Length(1) : Load "BanqueB/BoulesC.abk",1
End If
Load "BanqueI/Ftdb.abk" : NBI=Length(2)
If I$<>"" Then Load "BanqueI/"+I$+".abk",2
Make Icon Mask : Hide On
End Proc
Procedure PREFERENCES[CHOIX]
PRFV: Data "voice","sounds","language","speed","music"
PRF1: Data 0,0,6,0,10,7,1,"voice"
PRF2: Data 1,0,69,0,73,7,2,"sounds"
PRF3: Data 1,1,37,15,41,21,3,"Language"
PRF4: Data 0,2,6,30,13,35,8,"speed"
PRF5: Data 1,2,69,30,74,35,9,"music"
DRAPEAUX: Data 3,4,6,0,11,5,0,0,0,0,0,0,7
DIALECTES: Data "Ang","Ang","All","Fra","Esp","Ita","","","","","","","Jap"
SUITE_D_OPTIONS: Data 2,3,4,5,6,13,4,4,4,4,4,4,1
CLOCK[300,150] : B$="A.PeTdbacc" : BANQBI[B$,""] : ZB=Length(1)+1 : TB=10
ECR=Screen : ZCR=4
Screen Open ZCR,112,66,64,Lowres : Flash Off
Screen ZCR : Flash Off : Get Palette ECR : Cls 0
Screen To Front ECR : Screen ZCR : Paste Bob 0,0,TB : Wait Vbl
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Paste Bob E,F,Z
Else
If PREF(X) : Paste Bob E,F,Z : End If
End If
Next : Get Bob ZCR,ZB,0,0 To 111,63 : Screen ECR
PARLE["Choose",2] : Hide On
If CHOIX=0 : H=40 : V=73
For Z=1 To 64 Step 2
ZZ=Min(2*Z,112) : Get Bob ZCR,ZB,0,0 To ZZ,Z : Bob 1,H,V,ZB : Wait Vbl
Next
Else
Bob 1,400,10,ZB : Wait Vbl
If CHOIX=1
Limit Bob 1,0,0 To 224,200
Channel 1 To Bob 1 : Bob 1,222,120, : Wait Vbl
Amal 1,"M -112,0,28" : Amal On 1 : While Chanmv(1) : Wend
H=110 : V=120
Else
Limit Bob 1,158,0 To 400,200
Channel 1 To Bob 1 : Bob 1,36,120, : Wait Vbl
Amal 1,"M 112,0,28" : Amal On 1 : While Chanmv(1) : Wend
H=148 : V=120
End If
End If
VIDCUR[0]
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z : Add E,H : Add F,V
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Bob X+1,E,F,Z
Else
If PREF(X)
Bob X+1,E,F,Z
Else
Bob X+1,E,F,NBK+16
End If : Wait Vbl
End If
Next : Bob 1,,,TB : Wait Vbl
'
'
VIDCUR[0] : K=0
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z,P$ : Add C,H : Add D,V
CUR(A,B,0)=C : CUR(A,B,1)=D : CUR(A,B,2)=X : Z(X)=Z
If K<1
Bob BCUR,CUR(A,B,0),CUR(A,B,1),NBK+17 : Wait Vbl : PARLE[P$,2]
TEMPS=Timer+50 : Repeat : K=Mouse Key : Until Timer>TEMPS or K>1
End If
Next
While Mouse Key : Wend
HCR=1 : VCR=2 : INICURS[1,1] : L$=LANGUE$
Do
CURSEUR[0] : If BOUTONB Then MZ=0 : BOUTONB=False
Exit If MZ=0 or Not(BOUTONS)
If MZ=3
Restore SUITE_D_OPTIONS : For X=1 To PREF(3) : Read PREF(3) : Next
Restore DIALECTES : For X=1 To PREF(3) : Read LANGUE$ : Next
Restore DRAPEAUX : For X=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If
Bob MZ+1,,,Z : Wait Vbl
Else
If PREF(MZ)
Bob MZ+1,,,NBK+16 : PREF(MZ)=0
Else
Bob MZ+1,,,Z(MZ) : PREF(MZ)=1
End If
End If : Wait Vbl
Restore PRFV : For X=1 To MZ : Read P$ : Next : PARLE[P$,2]
While Mouse Key : Wend
Loop
FINDEPREF:
AJOUR : BRUITB[100] : Amal Off 15 : Bob BCUR,,,NBK+16 : Wait Vbl
CX=1 : CY=0
Screen ZCR : Paste Bob 0,0,TB
For X=1 To 5 : Restore "PRF"+Str$(X)-" "
Read A,B,C,D,E,F,Z
If X=3
Restore DRAPEAUX : For XX=1 To PREF(3) : Read Z : Next
If Z=0 : Z=NBK+16 : End If : Paste Bob E,F,Z
Else
If PREF(X) : Paste Bob E,F,Z : End If
End If
Next
Get Bob ZCR,ZB,0,0 To 111,64 : Screen ECR : Bob 1,,,ZB : Wait Vbl
For X=2 To 6 : Bob X,,,NBK+16 : Next
If CHOIX=0 : Screen ZCR
For Z=64 To 1 Step -4
ZZ=Min(2*Z,112)
Get Bob ZCR,ZB,0,0 To ZZ,Z : Screen ECR : Bob 1,40,73,ZB : Wait Vbl
Next
Bob 1,,,NBK+16 : Wait Vbl : Bob Off 1 : Wait Vbl
Else
Channel 1 To Bob 1 : Bob 1,,,Length(1) : Wait Vbl
If CHOIX=1
Amal 1,"M 112,0,28" : Amal On 1 : While Chanmv(1) : Wend
Else
Amal 1,"M -112,0,28" : Amal On 1 : While Chanmv(1) : Wend
End If
End If : Screen Close ZCR
Limit Bob : Amal Off : Bob Off : AJOUR : CLOCK[300,150]
If L$<>LANGUE$
If CHOIX=0
A$="Decors/Entree"+LANGUE$ : PASSECRAN[A$,1,1,1]
End If
If CHOIX=1
Load "banqueI/Titror"+LANGUE$+".ABK" : Paste Icon 20,48,TEST
End If
End If
BANQBI["",""]
End Proc
Procedure NETTOIE[BLK]
Update : Wait Vbl : Update Off
Bob Clear : Put Cblock BLK : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Cblock BLK : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure AUTOBLOC[N,X,Y]
Update : Update Off : Wait Vbl
Bob Clear : Put Block N,X,Y : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block N,X,Y : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure ABLOC[N]
Update : Update Off : Wait Vbl
Bob Clear : Put Block N : Bob Draw : Screen Swap : Wait Vbl
Bob Clear : Put Block N : Bob Draw : Screen Swap : Wait Vbl
Update On
End Proc
Procedure AJOUR
Update : Wait Vbl : Update : Wait Vbl
End Proc
Procedure TIRE[M]
If M=0 Then SA$="" : Pop Proc
' Tire un nombre parmi M et nouveau dans SA$
M=M-1 : Repeat : I=1+Rnd(M) : Until Instr(SA$,Str$(I)+" ")=0
SA$=SA$+Str$(I)+" "
End Proc[I]
Procedure TIRB[M]
If M=0 Then SB$="" : Pop Proc
' Tire un nombre parmi M et nouveau dans SB$
M=M-1 : Repeat : I=1+Rnd(M) : Until Instr(SB$,Str$(I)+" ")=0
SB$=SB$+Str$(I)+" "
End Proc[I]
Procedure AFFECTE[DEB,NOMB,IMAGE]
' DEB : premier indice, NOMB : nombre total, premier compris
' IMAGE: l'image � affecter
Repeat : N=DEB+Rnd(NOMB-1) : Until 0=ZBI(N) : ZBI(N)=IMAGE
End Proc[N]
Procedure VIDE
Update : Bob Update Off : Wait Vbl
For N=1 To NB : Bob N,H(N),V(N),NBK+16 : Wait Vbl : Next
Update : Bob Update On
End Proc
Procedure PLACE
Update : Bob Update Off : Wait Vbl
For N=1 To NB : Bob N,H(N),V(N),ZBI(N) : Wait Vbl : Next
Update : Bob Update On
End Proc
Procedure VOISTEST
If(ETAPE>1) and(Screen=3)
DROITE[3,45]
Else
TPTS(TEST)=0 : METTOTAL["+",0,XT,YT] : DROITE[Screen,235] : DC=190
S=Screen : Screen Open 3,450,270,64,Lowres : Flash Off : Get Palette S
Screen To Front S : Screen Copy S,190,0,640,270 To 3,0,0
Screen Offset 3,85,0 : Screen Close S : Double Buffer
Erase 7 : Reserve As Chip Work 7,65000
A$="MRbruits/Brt4.sbk" : If Not(Exist(A$)) : A$="df0:Brt4.sbk" : End If
Load A$,7
End If
End Proc
Procedure POSEVAR
Screen Open 7,32,10,16,Lowres : Flash Off : Screen Hide 7 : Screen 7
For X=1 To 5 : Doke Phybase(0)+2*(X-1),PREF(X) : Next
For X=1 To 4 : Doke Phybase(0)+8+2*X,TPTS(X) : Next
End Proc
Procedure PRENDVAR
Screen Hide 7 : Screen 7
For X=1 To 5 : PREF(X)=Deek(Phybase(0)+2*(X-1)) : Next
For X=1 To 4 : TPTS(X)=Deek(Phybase(0)+8+2*X) : Next
Data "Ang","Ang","All","Fra","Esp","Ita","","","","","","","Jap"
Restore : For X=1 To PREF(3) : Read LANGUE$ : Next
Screen Close 7
End Proc
Procedure RETOUR
Erase 1 : Erase 2 : Del Block : Del Cblock
S=Screen : Screen Open 2,360,270,64,Lowres : Flash Off
Get Palette S : Screen To Front S
Screen Copy S,0,0,360,270 To 2,0,0 : Screen Close S
CLOCK[280,60] : Load Iff "Decors/Entree"+LANGUE$,1
Flash Off : Screen To Front 2
Colour 0,0 : Colour Back 0 : Wait Vbl : View
Screen 2 : Autoback 0 : Screen To Front 2 : N=0 : D=2
BRUIT[0,0,"antizoom"]
For X=0 To 130 Step 1 : Repeat
H1=X : H2=X+D : H4=350-X : H3=H4-D
V1=X : V2=X+D : V4=270-X : V3=V4-D
Screen Copy 1,H1,V1,H4,V2 To 2,H1,V1
Screen Copy 1,H3,V2,H4,V4 To 2,H3,V2
Screen Copy 1,H1,V3,H3,V4 To 2,H1,V3
Screen Copy 1,H1,V2,H2,V3 To 2,H1,V2
Wait Vbl : Screen Swap : Inc N
Until N>1 : Next
Screen Close 2
Colour 0,0 : Colour Back 0 : Wait Vbl : View
POSEVAR : Screen 1 : A$="A48.amos" : If Exist("df0:"+A$) Then A$="DF0:"+A$
Run A$
End Proc
'
Procedure XY
X0=0 : Y0=0 : Change Mouse 1 : Show On : Limit Mouse
Repeat
X=X Screen(X Mouse) : Y=Y Screen(Y Mouse)
If X<>X0 or Y<>Y0
Locate 35,1 : Print X;" " : Locate 35,2 : Print Y;" "
X0=X : Y0=Y
End If
K$=Inkey$ : Exit If K$<>""
Until Mouse Key
End Proc